[솔리디티] 5. 배열, 열거형(enum), 구조체 (calldata, memory)

🔑 코인 투자 추천 링크 🔑

블록체인 전문가들도 놓치기 쉬운 비트코인, 이더리움의 핵심 가치 - 인프런 | 강의

블록체인 기획자,개발자,회사 대표라면 반드시 한번은 봐야 하는 강의입니다. 따로 공부할 시간이 없었다면, 이 요약본 강의를 통해서 비트코인,이더리움 백서의 핵심을 이해할 수 있습니다., -

www.inflearn.com

1. 배열

1.1 솔리디티 배열

- 솔리디티에서 배열은 정적배열(컴파일시점), 동적배열로 사용이 가능하다.

- 아래 예제에서 getArr()의 경우 전체 배열을 반환할 수 있음.

그러나, 길이가 무한정 늘어날 수 있으므로 이러한 형태의 함수는 피해야 함.

push - 배열에 추가 (배열 길이가 1 증가)

pop - 배열에서 제거 (배열 길이가 1 감소)

remove - 삭제는 배열길이를 변경하진 않음. 아래 함수에서는 index의 값을 기본값으로 재설정 (이 경우 0)

example() - 메모리에 배열 생성, 정적 배열만 생성 가능

소스파일

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.13;

contract Array {
    // Several ways to initialize an array
    uint[] public arr;
    uint[] public arr2 = [1, 2, 3];
    // Fixed sized array, all elements initialize to 0
    uint[10] public myFixedSizeArr;

    function get(uint i) public view returns (uint) {
        return arr[i];
    }

    // Solidity can return the entire array.
    // But this function should be avoided for
    // arrays that can grow indefinitely in length.
    function getArr() public view returns (uint[] memory) {
        return arr;
    }

    function push(uint i) public {
        // Append to array
        // This will increase the array length by 1.
        arr.push(i);
    }

    function pop() public {
        // Remove last element from array
        // This will decrease the array length by 1
        arr.pop();
    }

    function getLength() public view returns (uint) {
        return arr.length;
    }

    function remove(uint index) public {
        // Delete does not change the array length.
        // It resets the value at index to it's default value,
        // in this case 0
        delete arr[index];
    }

    function examples() external {
        // create array in memory, only fixed size can be created
        uint[] memory a = new uint[](5);
    }
}

1.2 솔리디티 배열 요소 제거 예제1)

- 원하는 배열의 요소를 제거하고 이후부터 오른쪽에서 왼쪽으로 배열의 요소들을 이동

- remove() 에 입력된 배열의 데이터가 삭제되고, 배열의 데이터가 오른쪽에서 왼쪽으로 차례로 이동됨.

- remove() 함수 활용을 위한 test() 함수 작성 후, assert() 로 동작여부 확인

- assert()의 경우는 false일 경우 에러를 발생시키는데, 코딩 시 값 테스트를 위해서 유용하게 사용될 수 있음.

소스파일

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.13;

contract ArrayRemoveByShifting {
    // [1, 2, 3] -- remove(1) --> [1, 3, 3] --> [1, 3]
    // [1, 2, 3, 4, 5, 6] -- remove(2) --> [1, 2, 4, 5, 6, 6] --> [1, 2, 4, 5, 6]
    // [1, 2, 3, 4, 5, 6] -- remove(0) --> [2, 3, 4, 5, 6, 6] --> [2, 3, 4, 5, 6]
    // [1] -- remove(0) --> [1] --> []

    uint[] public arr;

    function remove(uint _index) public {
        require(_index < arr.length, "index out of bound");

        for (uint i = _index; i < arr.length - 1; i++) {
            arr[i] = arr[i + 1];
        }
        arr.pop();
    }

    function test() external {
        arr = [1, 2, 3, 4, 5];
        remove(2);
        // [1, 2, 4, 5]
        assert(arr[0] == 1);
        assert(arr[1] == 2);
        assert(arr[2] == 4);
        assert(arr[3] == 5);
        assert(arr.length == 4);

        arr = [1];
        remove(0);
        // []
        assert(arr.length == 0);
    }
}

1.3 솔리디티 배열 요소 제거 예제2)

- 원하는 배열 요소를 제거하고 제일 끝에 있는 요소를 제거한 배열로 대체

소스파일

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.13;

contract ArrayReplaceFromEnd {
    uint[] public arr;

    // Deleting an element creates a gap in the array.
    // One trick to keep the array compact is to
    // move the last element into the place to delete.
    function remove(uint index) public {
        // Move the last element into the place to delete
        arr[index] = arr[arr.length - 1];
        // Remove the last element
        arr.pop();
    }

    function test() public {
        arr = [1, 2, 3, 4];

        remove(1);
        // [1, 4, 3]
        assert(arr.length == 3);
        assert(arr[0] == 1);
        assert(arr[1] == 4);
        assert(arr[2] == 3);

        remove(2);
        // [1, 4]
        assert(arr.length == 2);
        assert(arr[0] == 1);
        assert(arr[1] == 4);
    }
}

2. Enum(열거형)

- 솔리디티에서는 열거형(enum)을 지원하며, 상태 추적 및 모델 선택에 유용함.

- Enum은 컨트랙트 밖에서 선언될 수 있음

소스파일

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.13;

contract Enum {
    // Enum representing shipping status
    enum Status {
        Pending,
        Shipped,
        Accepted,
        Rejected,
        Canceled
    }

    // Default value is the first element listed in
    // definition of the type, in this case "Pending"
    Status public status;

    // Returns uint
    // Pending  - 0
    // Shipped  - 1
    // Accepted - 2
    // Rejected - 3
    // Canceled - 4
    function get() public view returns (Status) {
        return status;
    }

    // Update status by passing uint into input
    function set(Status _status) public {
        status = _status;
    }

    // You can update to a specific enum like this
    function cancel() public {
        status = Status.Canceled;
    }

    // delete resets the enum to its first value, 0
    function reset() public {
        delete status;
    }
}

- 파일형태로 enum을 선언하고 불러오는 방법

- 아래와 같이 EnumDeclaration.sol 파일로 선언하고,